Embedded systems

Working principles:

• pin D2 is connected to the central pin of the microswitch. Depending on the switch position, the central pin will be connected to the left or right pin. If it is on the right, it leads to connect the central pin, and thus D2 to the ground, so 0V. If it is on the left, D2 will be tied to 3.3V, through a 20Ko resistor (i.e. a pull-up resistor that allows the current to flow to the µC pin). Thus, D2 is either at 0 of 3.3V,, which corresponds respectively to 0 and 1 when digitalRead() is used to read the pin state.
• pin D1 is used to switch on/off the led. The ESP8266 must be told to put a high or low state at this pin. In the present case, the led must be on if D2 is high, and off if D2 is low.

 

 What must be done :

• Start arduino and create a new sketch.
• Copy the following code to obtain the described behaviour (NB : some parts are useless for this exercise but will be for the others).

byte old_state;
byte state;
 
void setup() {
 
  Serial.begin(115200);
  delay(10);
 
  // power off Wifi to save energy
  WiFi.mode(WIFI_OFF);
  WiFi.forceSleepBegin();
  delay(10); 
 
  pinMode(D2,INPUT); // switch
  testSwitch(true); // first call to determine the initial state 
  pinMode(D1,OUTPUT); // LED
  digitalWrite(D1,LOW); // switch off the led at start
  delay(10);  
}
 
void testSwitch(bool init) {
  state = digitalRead(D2);  
  if ((init) || (old_state != state)) {
    if (state == 0) {
      Serial.println("switch off => light off");
      digitalWrite(D1,LOW);
    }
    else {
      Serial.println("switch on => light on");
      digitalWrite(D1,HIGH);    
    }  
    old_state = state;
  }
}
 
void loop() {
  testSwitch(false);
  delay(10); // attendre 10ms
}

• Save this sketch in the Arduino directory, giving a simple name, e.g.  simpletest.
• Connect the esp8266 to a USB port of the computer
• In menu "Tools", select "Type of card" : Wemos D1 R2 & mini.
• Check that :
  • upload speed is at 921600
  • port is /dev/ttyUSB0 (NB : if you have other connected boards, it may be ttyUSB1, ttyUSB2, ...)
• In menu "Tools", choose "Monitor". A new window appears (called the monitor in the following), that displays what is sent to the computer by the D1, thanks to the instructions  Serial.print(...). Unfortunately, it is the only way to debug a program. CAUTION ! In the bottom-right of this window, you have to set the speed to 115200 bauds. Otherwise, the computer will receive jammed data and display random characters.
• In menu "Sketch",  choose "Upload". The code is compiled then transfered in the flash memory of the D1. It compilation fails, there is a mistake in the code. If the transfer fails, the speed transfer may be invalid, or not adapted to the board. Try a lower speed (e.g. 460800 bauds, or even less)

Remarks :

• it is better to wait few millseconds between calls to testSwitch(), hence the instruction delay(10). Otherwise, the D1 may crash.
• It is also possible to use the interrupts principle to call testSwitch(). For example, we can tell the D1 to interrupt what it is currently doing to call a particular function (i.e. a callback) as soon as the state of pin D2 changes. It avoids to manipulate two variables to know if its state canged.

 

What must be done - first part :

#include <ESP8266WiFi.h>
 
// wifi infos : modify according to the AP config
const char* ssid     = "wifi_ssid";
const char* password = "wifi_passwd";
 
void setup() {
 
  Serial.begin(115200);
  delay(10);
  // connecting to a WiFi network
  Serial.println("Trying to connecting to "+String(ssid));
  /* Explicitly set the ESP8266 to be a WiFi-client, otherwise, it by default,
     would try to act as both a client and an access-point and could cause
     network-issues with your other WiFi-devices on your WiFi-network. */
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  // wait for the connection to establish 
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // log wifi config
  Serial.println("");
  Serial.println("WiFi connected");  
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}
 
void loop() {
  // put your code here (see next part of the exercise
  delay(100);
}

#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClient.h>
// variables used for wifi+http
WiFiClient client;
HTTPClient http;

// put setup here + wifi init + ...
 
void loop() {
   Serial.print("[HTTP] begin...\n");
   http.begin(client, "http://jigsaw.w3.org/HTTP/connection.html"); //HTTP
   Serial.print("[HTTP] GET...\n");
   // start connection and send HTTP header
   int httpCode = http.GET();
 
   // httpCode will be negative on error
   if(httpCode > 0) {
     // HTTP header has been send and Server response header has been handled
     Serial.printf("[HTTP] GET... code: %d\n", httpCode);
 
     // file found at server
     if(httpCode == HTTP_CODE_OK) {
       String payload = http.getString();
       Serial.println(payload);
     }
   } 
   else {
     Serial.printf("[HTTP] GET... failed, error: %s\n", http.errorToString(httpCode).c_str());
   }
   http.end();
   sleep(1000);
}

 

 

#include <Ultrasonic.h>
#define TRIGGER_PIN  D5
#define ECHO_PIN     D6

Ultrasonic ultrasonic(TRIGGER_PIN, ECHO_PIN);

void setup() {
  Serial.begin(115200); 
  pinMode(D1, OUTPUT);
  digitalWrite(D1, HIGH); // switch on the led
  pinMode(D2, INPUT);
  Serial.println("!!! started !!!");  
}

void loop() {
  long microsec = ultrasonic.timing();
  float dist = ultrasonic.convert(microsec, Ultrasonic::CM);  
  Serial.println(dist);  
  delay(500);
}

#include <ESP8266WiFi.h>
WiFiClient client;
const char* server = "192.168.0.2";
const int port = 12345;
int stateConn = 0; // state of connection to server
String idClient; // my id given by server.

// readLineServer() blocks until a line is read, or 1023 char have been read.
String readLineServer() {
  char buffer[1024];
  memset(buffer,0,1024);    // reset buffer
  int index = 0; 
  char c;  
  while(true) {
    while (!client.available()) {} // wait for smthg to read
    while ((index < 1023) && (client.available())) {
      c = client.read();
      if (c == '\n') return String(buffer); // end-of-line reached => return
      buffer[index++] = c; // store the char
    }
    if (index == 1023) return String(buffer); 
  }  
}

void serverConnection() {
  Serial.print("connecting to "+String(server));
  // Use WiFiClient class to create TCP connections
  if (!client.connect(server, port)) {
    Serial.println("connection failed");
    stateConn = 0;
  }
  else {   
    stateConn = 1;  
    Serial.println("connected to server. Asking my id");
    client.println("0"); // envoi requête GETID
    idClient = readLineServer();
    Serial.println("my id is "+idClient);    
  }
}

// add other function: setup(), setupWifi(), ...

void loop() {
  if (stateConn == 0) {    
    serverConnection();
    if (stateConn == 0) delay(2000);    
  }
  else {
    // fulfill the code
  }
}

 

For that exercise, a new library must be installed, that must handle the TM1637 chipset. This time, the library is intalled via the Library manager :

 

Here is a sketch pattern to use the chipset, with the "Grove 4-digit" library :

 

What must be done :

• Create a new sketch and copy/paste the code of the exercise #3 in it.
• Each time the distance is measured, this distance must be displayed, in centimeters (but rounded to an integer value) on the 3 first digits of the 4-digit display
• The fourth digit must display the state of the led, i.e. 0 if it is off, and 1 if it is on.

 

What must be done: